مثال لتعدد المهام في فري باسكال/لازاراس multi-threading

تكلمنا في تدوينة سابقة عن تعدد المهام والآن نُريد عمل مثال بلغة فري باسكال بإستخدام أداة التطوير لازاراس.

نقوم بإنشاء مشروع جديد من نوع Application ثم نضع فيه زر ومحرر نصوص TMemo كما في الشكل التالي:

ثم نكتب الكود التالي في حدث ضغط الزر:

Memo1.Lines.Add('Started at: ' + DateTimeToStr(Now));
Sleep(30000);
Memo1.Lines.Add('Finshed at: ' + DateTimeToStr(Now));

عند تشغيل البرنامج والضغط على الزر نُلاحظ أن البرنامج قد تجمد لمدة ٣٠ ثانية، خلالها لا يمكننا الضغط مرة أخرى على الزر أو الكتابة في المحرر مثلاً. وذلك لأن نظام التشغيل قد أعطاه مهمة رئيسية واحدة فقط، فهو إذا single thread application.

يتحرر البرنامج ويُصبح قابلاً للتفاعل مرة أخرى بعد إنتهاء الإجراء المرتبط بضغط الزر. وقد قمنا بإستخدام الدالة Sleep والتي تعطل التنفيذ لفترة، فيها محاكاة لتنفيذ أي إجراء يأخذ وقت.

لإضافة مهمة ثانوية thread في البرنامج لتعمل في الخلفية، نقوم بإنشاء فئة جديدة من النوع TThread في الوحدة الرئيسية فوق تعريف الفورم كالتالي:

TSampleThread = class(TThread)
public
  procedure execute; override;
end;

ثم نقوم بكتابة كود اﻹجراء execute كالتالي:

Sleep(30000);

ثم نقوم بإنشاء كائن من هذه الفئة في كود الزر كالتالي:

procedure TForm1.Button1Click(Sender: TObject);
var
  MySample: TSampleThread;
begin
  Memo1.Lines.Add('Started at: ' + DateTimeToStr(Now));
  MySample:= TSampleThread.Create(False);
end;

عند تشغيل البرنامج هذه المرة نُلاحظ أن لا يتجمد، بل يُمكننا الضغط على الزر أكثر من مرة قبل نهاية اﻹجراء السابق، لكن لا نعرف إذا ما إنتهى اﻷجراء اﻷول أم لا.

لمعرفة نهاية اﻹجراء نقوم بكتابة حدث وربطه بنهاية المهمة OnTerminate.

لكن قبل ذلك نريد عمل بعض اﻹضافات، وهي تعريف متغير ID لتسجيل رقم المهمة، لمعرفة أي مهمة إنتهت، كذلك نقوم بأجيل التشغيل قليلاً حتى نقوم بتهيأة كل متطلبات المهمة ثم نقوم بتشغيلها بواسطة اﻹجراء Resume.

يصبح كود الوحدة المعدل كالتالي:

unit main;

{$mode objfpc}{$H+}

interface

uses
Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls;

type

{ TSampleThread }

TSampleThread = class(TThread)
public
  ID: Integer;
  procedure execute; override;
end;

{ TForm1 }

TForm1 = class(TForm)
  Button1: TButton;
  Memo1: TMemo;

  procedure Button1Click(Sender: TObject);

  private
  { private declarations }
  public
    procedure Finished(Sender: TObject);
  { public declarations }
  end;

var
  Form1: TForm1;

implementation

{ TSampleThread }

procedure TSampleThread.execute;
begin
  Sleep(30000);
end;

procedure TForm1.Finished(Sender: TObject);
begin
  Form1.Memo1.Lines.Add('Thread # ' + IntToStr((Sender as TSampleThread).ID) +
    ' is finished at: ' + DateTimeToStr(Now));
end;

{$R *.lfm}

{ TForm1 }

procedure TForm1.Button1Click(Sender: TObject);
var
  MySample: TSampleThread;
begin
  MySample:= TSampleThread.Create(True);
  MySample.ID:= Random(100);
  MySample.OnTerminate:= @finished;
  MySample.Resume;
  Memo1.Lines.Add('Thread # ' + IntToStr(MySample.ID) + ' has started at: '
     + DateTimeToStr(Now));
end;

end.

عند تشغيله يمكننا الضغط أكثر من مرة على الزر لتوليد أكثر من مهمة ثم مراقبة إنتهائها الواحدة بعد اﻷخرى:

نلاحظ بعد تشغيل هذه المهام الفرعية أن المهمة الرئيسية main thread أيضاً متوفرة حيث يمكن الكتابة في المحرر أثناء اﻹنتظار.

يوجد شيء أخير متعلق بالموارد، وهي أن مكونات لازاراس المعروفة بالـ LCL غير أمنة مع تعدد المهام not thread-safe لذلك يُمكن أن تحدث مشكلة عند محاولة أكثر من مهمة الكتابة في نفس اللحظة، فنقوم بحل ذلك برمجياً بحماية هذا المورد بطريقة تُعرف بالـ synchronization وذلك لأن الكتابة تُعتبر نقطة حرجة critical section.

قُمنا بإضافة إجراء جديد في فئة المهمة أسميناه writeFinish وهو المسؤول عن الكتابة في المورد المشترك (المحرر) وهو يُمثل القسم الحرج critical section، حتى يسنى لنا ندائه بالدالة Synchornize والتي تضمن إصطفاف المهام عند محاولتها الكتابة في وقت واحد في نفس المورد.

يُصبح الكود المعدل كالتالي:

unit main;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls;

type

{ TSampleThread }

TSampleThread = class(TThread)
public
  ID: Integer;
  procedure execute; override;
  procedure writeFinish;
end;

{ TForm1 }

TForm1 = class(TForm)
  Button1: TButton;
  Memo1: TMemo;

  procedure Button1Click(Sender: TObject);

  private
  { private declarations }
  public
    procedure Finished(Sender: TObject);
  { public declarations }
  end;

var
  Form1: TForm1;

implementation

{ TSampleThread }

procedure TSampleThread.execute;
begin
  Sleep(30000);
end;

procedure TSampleThread.writeFinish;
begin
  Form1.Memo1.Lines.Add('Thread # ' + IntToStr(ID) +
    ' is finished at: ' + DateTimeToStr(Now));

end;

procedure TForm1.Finished(Sender: TObject);
var
  aThread: TSampleThread;
begin
  aThread := (Sender as TSampleThread);
  aThread.Synchronize(@aThread.writeFinish);
end;

{$R *.lfm}

{ TForm1 }

procedure TForm1.Button1Click(Sender: TObject);
var
  MySample: TSampleThread;
begin
  MySample:= TSampleThread.Create(True);
  MySample.ID:= Random(100);
  MySample.OnTerminate:= @finished;
  MySample.Resume;
  Memo1.Lines.Add('Thread # ' + IntToStr(MySample.ID) + ' has started at: '
     + DateTimeToStr(Now));
end;

end.